На этом шаге мы проведем небольшую оченку свободного пространства.

    Проанализируем оставшееся свободное пространство кузова автомобиля после погрузки первой партии ящиков по каждому варианту размещения. Необходимое условие для анализа - наглядность. С этой целью создадим две таблицы:

• определения размера оставшегося свободного пространства в кузове автомобиля между размещенным грузом и правым бортом кузова (А), задним бортом кузова (В) и потолком кузова (С). Эти размеры указаны на рисунке 1.

  
  Рис.1. Заполнение кузова автомобиля первой партией (выбрано расположение по варианту 1 - Ширина х Длина х Высота)

  Таблица расположена в области ячеек J13:L21 (рисунок 2);

  
  Рис.2. Таблица расчета размеров оставшегося свободного пространства кузова после загрузки первой партии

• определения каждого свободного объема, которые указывались при рассмотрении последовательности заполнения кузова автомобиля - область N13:Q21 (рисунок 3).

  
  Рис.3. Таблица расчета оставшегося свободного объема кузова

Создание таблицы расчета размеров оставшегося свободного пространства в кузове автомобиля

    При прямоугольных размерах груза, габариты первой партия груза также будут иметь прямоугольный размер. В зависимости от вариантов размещения первой партии, размеры между границами, занимаемого грузом и плоскостями, ограничивающими объем кузова, будет различен. Исходя из этого, составляющие таблицы на рисунке 1 должны рассчитывать эти размеры для всех вариантов расположения ящиков первой партии груза:

• область ячеек J16:J21 определяет длину свободного места от правой линии загруженных ящиков до правого борта кузова;
• область ячеек К16:К21 определяет длину свободного места от линии загруженных ящиков по длине кузова и до конца кузова;
• область ячеек L16:L21 определяет длину свободного места от верхней линии загруженных ящиков до потолка кузова.

    Формулы в этих областях однотипны, и проанализируем их по формуле, введенной в ячейку К16, которая производит вычисление свободного расстояния по длине кузова автомобиля:

  =ЕСЛИ(G16=0;Машина_Длина;ОКРУГЛ(Машина_Длина-E16*Груз_Длина;2))

    Функция ЕСЛИ анализирует, помещается ли груз в машину при данном варианте размещения и, если не помещается, то возвращает значение длины автомобиля. Если же груз помещается, то из значения длины кузова автомобиля вычитается значение расстояния, которое занимает габарит груза (по варианту размещения - длина, ширина или высота), умноженный на количество ящиков, размещенных по длине кузова.

    В других ячейках таблицы находятся похожие формулы, но используют комбинацию различных габаритов груза и кузова.

Определение составляющих оставшегося свободного объема кузова автомобиля

    Для анализа оставшегося свободного объема кузова автомобиля после погрузки первой партии ящиков, создайте в области ячеек N16:Q21 таблицу вычисления объема оставшегося пространства (рисуеок 3), которая позволит воспринимать визуально - из каких составляющих складывается объем оставшегося свободного пространства. В таблице находятся формулы, определяющие общий объем свободного пространства и составляющие этого объема:

• по ширине кузова - от правой линии габаритов загруженных ящиков до правого борта кузова по длине и на всю высоту кузова (партия-2). Область ячеек N16:N21. Пример рассчитываемого свободного объема показан на рисунке 4;

  
  Рис.4. Габариты пространства, заполняемого второй партией груза

• по длине кузова - от линии габаритов загруженных ящиков, находящуюся к концу кузова на всю ширину загруженных ящиков первой партии и на всю высоту кузова (партия-3). Область ячеек O16:O21. Пример рассчитываемого свободного объема показан на рисунке 5;

  
  Рис.5. Объем пространства, заполняемого третьей партией груза

• по высоте кузова - от верхней линии загруженных ящиков от первой партии до потолка кузова, а также на всю длину и ширину загруженной первой партии груза (партия-4). Область ячеек P16:P21.

Формулы таблицы расчета оставшегося свободного объема кузова

    Формулы вычисляющие оставшейся свободный объем кузова, можно разделить на две половины:

• левая часть формулы - показывает сомножители, участвующие в вычислениях;
• правая часть определяет объем свободного пространства путем перемножения указанных в левой части сомножителей.

    Рассмотрим формулы, находящиеся в первой строке указанных диапазонов таблицы.

    Формула в ячейке N16 основана на функции СЦЕПИТЬ, соединяющей текст, ссылки на ячейки, которым присвоены и не присвоены имена, а также производящая вычисление свободного объема, оставшегося по ширине автомобиля:

  =СЦЕПИТЬ(J16;" х ";Машина_Длина;" х ";Машина_Высота;
    " = ";J16*Машина_Длина*Машина_Высота)

    Формула в ячейке О16 аналогична предыдущей, но несколько сложнее:

  =СЦЕПИТЬ(L16;" х (";Машина_Длина;" - ";K16;") х (";Машина_Ширина;" - ";J16;") = ";
    ОКРУГЛ(L16*(Машина_Длина-K16)*(Машина_Ширина-J16);2))

    В качестве сомножителей участвуют вычисленные значения:

• оставшееся свободное пространство по высоте от верхней линии загруженной первой партии груза до потолка;
• длина автомобиля, уменьшенная на оставшееся свободное пространство в конце кузова автомобиля после загрузки первой партии груза от линии груза до заднего борта кузова;
• ширина автомобиля, уменьшенная на свободное пространство справа кузова автомобиля после загрузки первой партии груза.

    В формуле в ячейке Р16:

  =СЦЕПИТЬ(K16;" х (";Машина_Ширина;" - ";J16;") х ";Машина_Высота;
    " = ";ОКРУГЛ(K16*(Машина_Ширина-J16)*Машина_Высота;2))

• оставшееся свободное расстояние по длине кузова автомобиля;
• ширина автомобиля, уменьшенная на свободное пространство кузова автомобиля справа после загрузки первой партии груза;
• высота кузова автомобиля.

    В ячейке Q16 формула суммарного свободного объема автомобиля:

  =ОКРУГЛ((J16*Машина_Длина*Машина_Высота)+(L16*(Машина_Длина-K16)*
    (Машина_Ширина-J16))+(K16*(Машина_Ширина-J16)+Машина_Высота);3) 

    На следующем шаге мы рассмотрим дальнейшую загрузку автомобиля.

Предыдущий шаг Содержание Следующий шаг